Mikrotik RB750 default setting

Minggu, 16 Oktober 2011

#| ether1 is renamed ether1-gateway, rest of interfaces are switched
#| IP address 192.168.88.1/24 is on switch
#| DHCP client is on ether1-gateway
#| DHCP server is on switch, with address pool 192.168.88.10-192.168.88.254
#| masquerade on ether1-gateway
:global action

# these commands are executed after installation or configuration reset
:if ($action = "apply") do={
/interface set ether1 name=ether1-gateway
/interface set ether2 name=ether2-local-master
/interface set ether3 name=ether3-local-slave
/interface set ether4 name=ether4-local-slave
/interface set ether5 name=ether5-local-slave

/interface ethernet set ether3-local-slave master-port=ether2-local-master
/interface ethernet set ether4-local-slave master-port=ether2-local-master
/interface ethernet set ether5-local-slave master-port=ether2-local-master

/ip address add address=192.168.88.1/24 interface=ether2-local-master comment="default configuration"

:if ([:len [/system package find name="dhcp" !disabled]] != 0) do={
/ip dhcp-client add interface=ether1-gateway disabled=no comment="default configuration";
/ip pool add name=default-dhcp ranges=192.168.88.10-192.168.88.254;
/ip dhcp-server add name=default address-pool=default-dhcp interface=ether2-local-master disabled=no;
/ip dhcp-server network add address=192.168.88.0/24 gateway=192.168.88.1 dns-server=192.168.88.1 comment="default configuration";
}

/ip firewall {
filter add chain=input action=accept protocol=icmp comment="default configuration"
filter add chain=input action=accept connection-state=established in-interface=ether1-gateway comment="default configuration"
filter add chain=input action=accept connection-state=related in-interface=ether1-gateway comment="default configuration"
filter add chain=input action=drop in-interface=ether1-gateway comment="default configuration"
nat add chain=srcnat out-interface=ether1-gateway action=masquerade comment="default configuration"
}

/ip dns {
set allow-remote-requests=yes
static add name=router address=192.168.88.1
}

/tool mac-server remove [find]
/tool mac-server add interface=ether2-local-master disabled=no
/tool mac-server add interface=ether3-local-slave disabled=no
/tool mac-server add interface=ether4-local-slave disabled=no
/tool mac-server add interface=ether5-local-slave disabled=no

/tool mac-server mac-winbox disable [find]
/tool mac-server mac-winbox add interface=ether2-local-master disabled=no
/tool mac-server mac-winbox add interface=ether3-local-slave disabled=no
/tool mac-server mac-winbox add interface=ether4-local-slave disabled=no
/tool mac-server mac-winbox add interface=ether5-local-slave disabled=no

/ip neighbor discovery set [find name=ether1-gateway] discover=no
}

# these commands are executed if user requests to remove default configuration
:if ($action = "revert") do={
/ip firewall {
:local o [nat find comment="default configuration"]
:if ([:len $o] != 0) do={ nat remove $o }

:local o [filter find comment="default configuration"]
:if ([:len $o] != 0) do={ filter remove $o }
}

:if ([:len [/system package find name="dhcp" !disabled]] != 0) do={
:local o [/ip dhcp-server network find comment="default configuration"]
:if ([:len $o] != 0) do={ /ip dhcp-server network remove $o }

:local o [/ip dhcp-server find name="default" address-pool="default-dhcp" interface=ether2-local-master !disabled]
:if ([:len $o] != 0) do={ /ip dhcp-server remove $o }

/ip pool {
:local o [find name=default-dhcp ranges=192.168.88.10-192.168.88.254]
:if ([:len $o] != 0) do={ remove $o }
}

:local o [/ip dhcp-client find comment="default configuration"]
:if ([:len $o] != 0) do={ /ip dhcp-client remove $o }
}

/ip dns {
set allow-remote-requests=no
:local o [static find name=router address=192.168.88.1]
:if ([:len $o] != 0) do={ static remove $o }
}

/ip address {
:local o [find comment="default configuration"]
:if ([:len $o] != 0) do={ remove $o }
}

/tool mac-server remove [find]
/tool mac-server add interface=all disabled=no

/tool mac-server mac-winbox remove [find interface!=all]
/tool mac-server mac-winbox set [find] disabled=no

/ip neighbor discovery set [find name=ether1-gateway] discover=yes

/interface ethernet set ether3-local-slave master-port=none
/interface ethernet set ether4-local-slave master-port=none
/interface ethernet set ether5-local-slave master-port=none

/interface set ether1-gateway name=ether1
/interface set ether2-local-master name=ether2
/interface set ether3-local-slave name=ether3
/interface set ether4-local-slave name=ether4
/interface set ether5-local-slave name=ether5
}

Memblokir Situs Dengan MikroTik Pada Jam Tertentu

Kamis, 13 Oktober 2011

Saat ini siapa sih yang nggak kenal dengan Facebook?? Situs jejaring yang banyak digunakan oleh orang-orang untuk mencari teman, chatting, dan sebagainya. Namun ternyata situs tersebut juga menjadi hambatan bagi perusahaan untuk melakukan kegiatan bisnisnya. Kenapa?? Salah satu penyebabnya adalah menjadikan para karyawannya sibuk facebook-an, sehingga melupakan tugas-tugas pokoknya. Tidak terkecuali kantor dimana saya bekerja menjadi korban demam facebook yang menjangkiti para karyawannya. Suatu hari saya diminta oleh atasan untuk memblokir situs Facebook agar tidak bisa diakses oleh para karyawan di kantor selama jam kerja, sedangkan diluar jam kerja diijinkan untuk mengakses situs tersebut.

Berhubung saya menggunakan MikroTik sebagai router, maka saya akan berbagi tips pemblokiran ala MikroTik. Berikut ini langkah-langkahnya. Semoga bermanfaat....

Pertama, supaya waktu yang berjalan di router sesuai dengan waktu lokasi setempat, maka kita perlu mengatur agar clock di MikroTik mengacu pada NTP Server. Jika kita memiliki NTP Server sendiri, maka kita tinggal mengarahkan MikroTik ke NTP Server tersebut, namun jika kita tidak memiliki NTP Server, maka tidak perlu khawatir karena banyak NTP Server di luar yang bisa kita gunakan sebagai acuan. Beberapa diantaranya adalah NTP Server milik LIPI (Lembaga Ilmu Pengetahuan Indonesia) dengan URL: ntp.kim.lipi.go.id (203.160.128.6) dan NTP Pool Project dengan salah satu URLnya: 0.id.pool.ntp.org (202.169.224.16). Untuk mensettingnya di MikroTik, ketikkan perintah berikut :

/system ntp client set primary-ntp=203.160.128.6 secondary-ntp=202.169.224.16 \ mode=unicast enabled=yes;

Kedua, membuat rule di firewall filter. Dalam hal ini saya ingin memblokir situs Facebook yang menggunakan port HTTP (80), sehingga selain port tersebut masih diijinkan. Tujuannya agar pengguna masih dapat menerima update status facebook melalui email. Untuk mensettingnya ketikkan perintah berikut :

/ip firewall filter add chain=forward src-address=0.0.0.0/0 protocol=tcp \ dst-port=80 content="facebook" action=drop comment="Blokir Akses Facebook";

Ketiga, membuat script untuk mengaktifkan firewall tersebut selama jam kerja dan mematikannya pada jam istirahat dan diluar jam kerja. Disini saya membuat 3 script, yaitu script untuk mengaktifkan (enable) firewall, script untuk mematikan (disable) firewall serta script untuk dieksekusi pada hari libur (Sabtu-Minggu) dan hari kerja. Berikut ini scriptnya :

Script untuk mematikan (disable) firewall :

/system script add name="fb-allow" policy=write,read,policy,test,sniff source={/ip firewall filter set [/ip firewall filter find content="facebook"] disabled=yes}



Script untuk mengaktifkan (enable) firewall :

/system script add name="fb-deny" policy=write,read,policy,test,sniff source={/ip firewall filter set [/ip firewall filter find content="facebook"] disabled=no}



Script untuk disable firewall di hari libur dan enable di hari kerja :

/system script add name="fb-holiday" policy=write,read,policy,test,sniff source={:if ([/system scheduler get [/system scheduler find on-event="fb-deny"] disabled] = true) do [/system scheduler set [/system scheduler find on-event="fb-deny"] disabled=no] else [/system scheduler set [/system scheduler find on-event="fb-deny"] disabled=yes]}

Keempat, membuat schedule untuk menentukan kapan firewall tersebut akan diaktifkan atau dinon-aktifkan. Disini saya membuat 6 scheduler berdasarkan jam kerja dan hari kerja, yaitu jam 08:00, jam 12:00, jam 13:00, jam 17:00, hari sabtu-minggu, dan hari senin. Berikut ini scriptnya :

Schedule untuk mengaktifkan (enable) firewall pada jam kerja (08:00) :

/system scheduler add name="fb-08:00" start-date=jan/01/1970 start-time=08:00:00 interval=1d on-event="fb-deny"

Schedule untuk mematikan (disable) firewall pada jam istirahat (12:00) :

/system scheduler add name="fb-12:00" start-date=jan/01/1970 start-time=12:00:00 interval=1d on-event="fb-allow"


Schedule untuk mengaktifkan kembali (enable) firewall pada jam kerja (13:00) :

/system scheduler add name="fb-13:00" start-date=jan/01/1970 start-time=13:00:00 interval=1d on-event="fb-deny"



Schedule untuk mematikan (disable) firewall di luar jam kerja ke atas ( > 17:00) :

/system scheduler add name="fb-17:00" start-date=jan/01/1970 start-time=17:00:00 interval=1d on-event="fb-allow"



Schedule untuk mematikan (disable) firewall di hari libur (Sabtu-Minggu) :

/system scheduler add name="fb-sabtu-minggu" start-date=aug/01/2009 start-time=00:00:00 interval=7d on-event="fb-holiday"

Pastikan bahwa tanggal yang didefinisikan pada parameter "start-date" scheduler adalah Hari Sabtu. Dan parameter "interval" diberi nilai 7d.

Schedule untuk mengaktifkan kembali (enable) firewall di hari kerja (Senin) :

/system scheduler add name="fb-senin" start-date=aug/03/2009 start-time=00:00:00 interval=7d on-event="fb-holiday"

Pastikan bahwa tanggal yang didefinisikan pada parameter "start-date" scheduler adalah Hari Senin. Dan parameter "interval" diberi nilai 7d.